Daniel Nashed's Blog

Check the minimum client version for your Notes application

Notes provides new functionality in Lotus Script and there also Java classes added to the client.
Lotus Script Named documents have been introduced in Notes/Domino 12.0.1.
I have just written an application which needs a Java class which is introduced in Notes 12.0.2 as it turned out.

So I came up with a simple check I am going to add to all my applications which use more current functionality.
You can drop this code into the PostOpen script of any database and switch to the right constant





Function CheckRequiredVersion As Boolean
       
        Const  BuildVersion1201 = "12.0.1|470"
        Const  BuildVersion1202 = "12.0.2|475"
        Const  BuildVersion1400 = "14.0|485"
        Const  BuildVersion1450 = "14.5|495"
       
        Const RequiredVersion = BuildVersion1202
       
        Const TXT_TITLE = "Please upgrade your Notes Client"
       
        Dim  CR  As String
        CR = Chr(10)
       
        Dim session As New NotesSession
        Dim CurrentBuildVersion As Long
        Dim CurrentNotesReleaseStr As String
        Dim CurrentNotesBuildDateStr As String
       
        Dim RequiredBuildVersion As Long
        Dim RequiredNotesReleaseStr As String
       
        CheckRequiredVersion = False
       
        RequiredNotesReleaseStr = Strtoken (RequiredVersion, "|",1)
        RequiredBuildVersion = Clng(Strtoken (RequiredVersion, "|",2))
       
        CurrentBuildVersion = session.NotesBuildVersion
        CurrentNotesReleaseStr = Strtoken (session.NotesVersion, "|",1)
        CurrentNotesBuildDateStr = Strtoken (session.NotesVersion, "|",2)
       
        If (CurrentBuildVersion >= RequiredBuildVersion) Then
                CheckRequiredVersion = True
                Exit Function
        End If
       
        Messagebox " You are running:  " +  CurrentNotesReleaseStr  + CR + CR + " This application requires:  " +  "Release " + RequiredNotesReleaseStr, 48, TXT_TITLE
       
End Function

• Comments [1]